Der Windows-Datei-Explorer ist einfach zu navigieren und bietet so viele interessante Barrierefreiheitsfunktionen, von denen eine die Ordneransichtseinstellungen sind. Sie können Ordner anpassen, um den Dateityp darzustellen, den sie speichern.

Wenn Sie beispielsweise einen Ordner haben, in dem Sie nur Videos gespeichert haben, können Sie den Ordner so einstellen, dass Miniaturansichten der Videos anstelle einer Liste oder Dateidetails angezeigt werden. Sie können auch jeden Ordner so anpassen, dass mittlere, große oder extragroße Symbole angezeigt werden.

Nachdem Sie diese Änderungen vorgenommen haben, möchten Sie sie möglicherweise sichern, um die Ordneransichtseinstellungen wiederherzustellen, wenn sie zurückgesetzt werden. Diese Anleitung zeigt Ihnen, wie Sie Ihre Ordneransichtseinstellungen mithilfe einer Batchdatei sichern und wiederherstellen.

Sichern und Wiederherstellen der Ordneransichtseinstellungen in Windows 11/10

Führen Sie die folgenden Schritte aus, um Ihre Ordneransichtseinstellungen in Windows 11/10 zu sichern und wiederherzustellen.

1. Erstellen Sie die Backup-and-Restore-Batchdatei.
2. Entsperren Sie die .bat-Datei, wenn sie von Windows blockiert wird.
3. Führen Sie die .bat-Datei aus, um Ihre Ordneransichtseinstellungen zu sichern und wiederherzustellen.

Ohne weitere Umschweife springen wir jetzt direkt in die detaillierten Schritte, die zur Durchführung der oben genannten Operationen erforderlich sind.

1]Erstellen Sie die Backup-and-Restore-Batchdatei

Klicken Sie auf die Start anklicken und suchen Notizblock. Wählen Sie die Notepad-App aus den Suchergebnissen aus, um sie zu starten.

Geben Sie den folgenden Text in die neue Notepad-Datei ein:

@ECHO OFF

title Backup and Restore Folder View Settings Tool
:choice
cls
echo.
echo OPTIONS:
echo.
echo 1. Back up your folder view settings.
echo 2. Restore folder view settings from backup.
echo 3. Cancel
echo.
echo.
set /P c=Type the option number you would like to do, and press Enter?
if /I "%c%" EQU "1" goto :verify1
if /I "%c%" EQU "2" goto :verify2
if /I "%c%" EQU "3" exit
goto :choice

:verify1
IF EXIST "%userprofile%\Desktop\Folder View Settings Backup" goto :response1
goto :backup

:response1
echo.
echo.
echo You already have a "Folder View Settings Backup" folder on your desktop.
echo Please move it to another location, and try again.
echo.
pause
goto :choice

:backup
mkdir "%userprofile%\Desktop\Folder View Settings Backup"
REG EXPORT HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Streams\Defaults "%userprofile%\Desktop\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_CurrentVersion_Explorer_Streams_Defaults.reg" /y
REG EXPORT HKCU\Software\Microsoft\Windows\Shell\BagMRU "%userprofile%\Desktop\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_Shell_BagMRU.reg" /y
REG EXPORT HKCU\Software\Microsoft\Windows\Shell\Bags "%userprofile%\Desktop\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_Shell_Bags.reg" /y
REG EXPORT HKCU\Software\Microsoft\Windows\ShellNoRoam\Bags "%userprofile%\Desktop\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_ShellNoRoam_Bags.reg" /y
REG EXPORT HKCU\Software\Microsoft\Windows\ShellNoRoam\BagMRU "%userprofile%\Desktop\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_ShellNoRoam_BagMRU.reg" /y
REG EXPORT "HKCU\Software\Classes\Local Settings\Software\Microsoft\Windows\Shell\BagMRU" "%userprofile%\Desktop\Folder View Settings Backup\HKCU_Software_Classes_LocalSettings_Software_Microsoft_Windows_Shell_BagMRU.reg" /y
REG EXPORT "HKCU\Software\Classes\Local Settings\Software\Microsoft\Windows\Shell\Bags" "%userprofile%\Desktop\Folder View Settings Backup\HKCU_Software_Classes_LocalSettings_Software_Microsoft_Windows_Shell_Bags.reg" /y
cls
echo.
echo Backup of folder view settings successfully completed.
echo.
pause 
exit

:verify2
IF NOT EXIST "%userprofile%\Desktop\Folder View Settings Backup" goto :response
goto :restore

:response
echo.
echo.
echo You do not have a "Folder View Settings Backup" folder on your desktop.
echo Please place the backup folder on your desktop, and try again.
echo.
pause
goto :choice

:restore 
REG Delete "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Streams\Defaults" /F
Reg Delete "HKCU\Software\Microsoft\Windows\Shell\BagMRU" /F
Reg Delete "HKCU\Software\Microsoft\Windows\Shell\Bags" /F
Reg Delete "HKCU\Software\Microsoft\Windows\ShellNoRoam\Bags" /F
Reg Delete "HKCU\Software\Microsoft\Windows\ShellNoRoam\BagMRU" /F
Reg Delete "HKCU\Software\Classes\Local Settings\Software\Microsoft\Windows\Shell\BagMRU" /F
Reg Delete "HKCU\Software\Classes\Local Settings\Software\Microsoft\Windows\Shell\Bags" /F

REG IMPORT "%userprofile%\Desktop\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_CurrentVersion_Explorer_Streams_Defaults.reg"
REG IMPORT "%userprofile%\Desktop\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_Shell_BagMRU.reg"
REG IMPORT "%userprofile%\Desktop\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_Shell_Bags.reg"
REG IMPORT "%userprofile%\Desktop\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_ShellNoRoam_Bags.reg"
REG IMPORT "%userprofile%\Desktop\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_ShellNoRoam_BagMRU.reg"
REG IMPORT "%userprofile%\Desktop\Folder View Settings Backup\HKCU_Software_Classes_LocalSettings_Software_Microsoft_Windows_Shell_BagMRU.reg"
REG IMPORT "%userprofile%\Desktop\Folder View Settings Backup\HKCU_Software_Classes_LocalSettings_Software_Microsoft_Windows_Shell_Bags.reg"
cls
echo.
echo Backup of folder view settings successfully restored.
echo.
echo Waiting to restart explorer to apply.
echo Your screen will flash as explorer is restarted.
echo.
echo.
pause
taskkill /f /im explorer.exe
start explorer.exe 
exit

Sie können den obigen Text kopieren und in die Notiz einfügen. Als nächstes drücken STRG + S und speichern Sie die Datei auf Ihrem Desktop mit dem .Schläger Verlängerung. Tun Sie dies, indem Sie hinzufügen .Schläger am Ende des Dateinamens vor dem Drücken der Speichern Taste.

Dateien, die in der Erweiterung .bat gespeichert sind, sind Batch-Dateien und wenn sie richtig gemacht werden, können Sie Befehle auf Ihrem Windows-System ausführen. Erfahren Sie mehr über Batch-Dateien und entdecken Sie diese coolen Tricks.

2]Entsperren Sie die .bat-Datei

Nach erfolgreichem Speichern der neu erstellten Datei als .Schläger Datei, kann Windows sie blockieren. Um diese Datei auszuführen, müssen Sie sie zuerst entsperren. Klicken Sie dazu mit der rechten Maustaste auf die Datei und wählen Sie sie aus Eigenschaften aus dem Kontextmenü.

Wechseln Sie zu Allgemein Registerkarte des Eigenschaftenfensters und suchen Sie die Entsperren Kontrollkästchen am unteren Rand des Fensters. Aktivieren Sie dieses Kontrollkästchen und klicken Sie auf OK Schaltfläche, um die Stapeldatei zu entsperren.

HINWEIS: Wenn die Entsperren das Kontrollkästchen in Ihrem Setup fehlt, bedeutet dies, dass Windows die Datei nicht blockiert hat und Sie mit dem nächsten Schritt fortfahren können.

3]Führen Sie die .bat-Datei aus

Nachdem Sie die .bat-Datei entsperrt haben, können Sie loslegen. Sie können die .bat-Datei ausführen, indem Sie darauf doppelklicken. Das Ausführen der Batchdatei öffnet ein Eingabeaufforderungsfenster, das Ihnen die folgenden Optionen zeigt:

• Sichern Sie Ihre Ordneransichtseinstellungen.
• Stellen Sie die Ordneransichtseinstellungen aus der Sicherung wieder her.
• Stornieren.

Um Ihre Ordneransichtseinstellungen zu sichern, drücken Sie 1 und drücken Sie die ENTER-Taste. Wenn Sie Ihre Ordneransichtseinstellungen wiederherstellen möchten, drücken Sie 2 und drücken Sie ENTER.

Alternativ drücken 3 um den Vorgang abzubrechen.

Hoffe das hilft.